Restaurar una base de datos al punto de error en el modelo de recuperación completa (Transact-SQL)

En este tema se explica cómo restaurar al punto de error. El tema solo es relevante para las bases de datos que usan los modelos de recuperación completos o optimizados para cargas masivas de registros.

Para restaurar al punto de error

1. Realice una copia de seguridad de la cola del registro mediante la ejecución de la siguiente instrucción básica de BACKUP :

   BACKUP LOG <database_name> TO <backup_device>   
      WITH NORECOVERY, NO_TRUNCATE;  
   

2. Restaure una copia de seguridad completa de la base de datos mediante la ejecución de la siguiente instrucción BÁSICA RESTORE DATABASE :

   RESTORE DATABASE <database_name> FROM <backup_device>   
      WITH NORECOVERY;  
   

3. Opcionalmente, restaure una copia de seguridad diferencial de la base de datos mediante la ejecución de la siguiente instrucción RESTORE DATABASE:

   RESTORE DATABASE <database_name> FROM <backup_device>   
      WITH NORECOVERY;  
   

4. Aplique cada registro de transacciones, incluida la copia de seguridad del final del registro que creó en el paso 1, especificando WITH NORECOVERY en la instrucción RESTORE LOG:

   RESTORE LOG <database_name> FROM <backup_device>   
      WITH NORECOVERY;  
   

5. Recupere la base de datos mediante la ejecución de la siguiente instrucción RESTORE DATABASE:

   RESTORE DATABASE <database_name>   
      WITH RECOVERY;  
   

Ejemplo

Para poder ejecutar el ejemplo, debe completar los siguientes preparativos:

1. El modelo de recuperación predeterminado de la base de datos AdventureWorks2012 es el modelo de recuperación simple. Dado que este modelo de recuperación no admite la restauración al punto de error, establezca AdventureWorks2012 para usar el modelo de recuperación completa ejecutando la siguiente instrucción ALTER DATABASE :

   USE master;  
   GO  
   ALTER DATABASE AdventureWorks2012 SET RECOVERY FULL;  
   

2. Cree una copia de seguridad completa de la base de datos mediante la siguiente instrucción BACKUP:

   BACKUP DATABASE AdventureWorks2012 TO DISK = 'C:\AdventureWorks2012_Data.bck';  
   

3. Cree una copia de seguridad de registros rutinaria:

   BACKUP LOG AdventureWorks2012 TO DISK = 'C:\AdventureWorks2012_Log.bck';  
   

En el ejemplo siguiente se restauran las copias de seguridad creadas anteriormente, después de crear una copia de seguridad final del registro de la base de datos AdventureWorks2012 . (En este paso se supone que se puede acceder al disco de registro).

En primer lugar, el ejemplo crea una copia de seguridad final del registro de la base de datos que captura el registro activo y deja la base de datos en el estado Restaurar. A continuación, el ejemplo restaura la copia de seguridad de la base de datos, aplica la copia de seguridad de registros de rutina creada anteriormente y aplica la copia de seguridad del registro de cola. Por último, el ejemplo recupera la base de datos en un paso independiente.

/* Example of restoring a to the point of failure */  
-- Step 1: Create a tail-log backup by using WITH NORECOVERY.  
BACKUP LOG AdventureWorks2012  
   TO DISK = 'C:\AdventureWorks2012_Log.bck'  
   WITH NORECOVERY;  
GO  
-- Step 2: Restore the full database backup.  
RESTORE DATABASE AdventureWorks2012  
   FROM DISK = 'C:\AdventureWorks2012_Data.bck'  
   WITH NORECOVERY;  
GO  
-- Step 3: Restore the first transaction log backup.  
RESTORE LOG AdventureWorks2012  
   FROM DISK = 'C:\AdventureWorks2012_Log.bck'  
   WITH NORECOVERY;  
GO  
-- Step 4: Restore the tail-log backup.  
RESTORE LOG AdventureWorks2012  
   FROM  DISK = 'C:\AdventureWorks2012_Log.bck'  
   WITH NORECOVERY;  
GO  
-- Step 5: Recover the database.  
RESTORE DATABASE AdventureWorks2012  
   WITH RECOVERY;  
GO  

Véase también

BACKUP (Transact-SQL)
RESTORE (Transact-SQL)